Функция НОД (наибольший общий делитель) на VBA

Function NOD(ParamArray args() As Variant)
    ' в качестве параметра получает список диапазонов ячеек произвольного размера
    ' возвращает НОД (наибольший общий делитель) чисел из диапазонов-аргументов
    ' По сути, является аналогом функции НОД из Excel2007

    Application.Volatile True    ' автопересчёт при изменениях на листе
    Dim ra As Range, cell As Range: On Error Resume Next
    Dim coll As New Collection    ' коллекция для уникальных чисел из списка параметров

    For Index = LBound(args) To UBound(args)    ' перебираем все диапазоны ячеек
        If Not IsMissing(args(Index)) Then    ' если очередной аргумент присутствует

            If TypeName(args(Index)) = "Range" Then    ' если аргумент - диапазон ячеек
                For Each cell In args(Index).Cells    ' перебираем все ячейки в диапазоне
                    num = Fix(Val(cell.Value))    ' отбрасываем дробную часть числа, если не ноль
                    If num > 0 Then coll.Add num, CStr(num)    ' добавляем в коллекцию
                    ' если в ячейке - не число, то возвращаем ошибку #ЗНАЧ!
                    If Not IsNumeric(cell.Value) Then NOD = CVErr(1): Exit Function
                    If num < 0 Then NOD = CVErr(2036): Exit Function    ' возвращаем ошибку #ЧИСЛО!
                Next cell
 
            ElseIf IsNumeric(args(Index)) Then    ' если аргумент - число
                num = Fix(Val(args(Index)))    ' отбрасываем дробную часть числа
                If num > 0 Then coll.Add num, CStr(num)    ' добавляем в коллекцию, если не ноль
                ' если аргумент - не число, то возвращаем ошибку #ЗНАЧ!
                If Not IsNumeric(args(Index)) Then NOD = CVErr(1): Exit Function
                If num < 0 Then NOD = CVErr(2036): Exit Function    ' возвращаем ошибку #ЧИСЛО!
            End If
        End If
    Next Index
 
    ' алгоритм взят отсюда:   programmersforum.ru/showpost.php?p=178157&postcount=17
    Dim G As Long: G = coll(1): NOD = G
    If coll.Count = 1 Then Exit Function
    For i = 2 To coll.Count
        G = GCD(IIf(G < coll(i), G, coll(i)), IIf(G < coll(i), coll(i), G))
    Next
    NOD = G
End Function
 
Function GCD(a As Long, b As Long) As Long
    ' используется рекурсивный вызов
    Dim d As Long
    d = b Mod a
    If d = 0 Then GCD = a Else GCD = GCD(d, a)
End Function