mail mail
Нужен макрос для Excel?
Сделайте заказ прямо сейчас!
Ищете готовое решение?
Выбирайте и покупайте!
У вас есть интернет-магазин?
Настроим парсер под любой сайт!

Вывод диалоговых окон выбора файла и папки средствами VBA (выбрать файл или папку)

Функции GetFileName и GetFilePath по сути аналогичны, и предназначены для вывода диалогового окна выбора файла
(при этом можно указать стартовую папку для поиска файла, и тип/расширение выбираемого файла)

Функция GetFilenamesCollection позволяет выборать сразу несколько файлов в одной папке.

Функция GetFolderPath работает также, только служит для вывода диалогового окна выбора папки.

Function GetFolderPath(Optional ByVal Title As String = "Выберите папку", _
                       Optional ByVal InitialPath As String = "c:\") As String
    ' функция выводит диалоговое окно выбора папки с заголовком Title,
    ' начиная обзор диска с папки InitialPath
    ' возвращает полный путь к выбранной папке, или пустую строку в случае отказа от выбора
    Dim PS As String: PS = Application.PathSeparator
    With Application.FileDialog(msoFileDialogFolderPicker)
        If Not Right$(InitialPath, 1) = PS Then InitialPath = InitialPath & PS
        .ButtonName = "Выбрать": .Title = Title: .InitialFileName = InitialPath
        If .Show <> -1 Then Exit Function
        GetFolderPath = .SelectedItems(1)
        If Not Right$(GetFolderPath, 1) = PS Then GetFolderPath = GetFolderPath & PS
    End With
End Function
 
Sub ПримерИспользования_GetFolderPath()
    ПутьКПапке = GetFolderPath("Заголовок окна", ThisWorkbook.Path)   ' запрашиваем имя папки
    If ПутьКПапке = "" Then Exit Sub    ' выход, если пользователь отказался от выбора папки
    MsgBox "Выбрана папка: " & ПутьКПапке, vbInformation
End Sub

Function GetFilePath(Optional ByVal Title As String = "Выберите файл для обработки", _
                     Optional ByVal InitialPath As String = "c:\", _
                     Optional ByVal FilterDescription As String = "Книги Excel", _
                     Optional ByVal FilterExtention As String = "*.xls*") As String
    ' функция выводит диалоговое окно выбора файла с заголовком Title,
    ' начиная обзор диска с папки InitialPath
    ' возвращает полный путь к выбранному файлу, или пустую строку в случае отказа от выбора
    ' для фильтра можно указать описание и расширение выбираемых файлов
    On Error Resume Next
    With Application.FileDialog(msoFileDialogOpen)
        .ButtonName = "Выбрать": .Title = Title: .InitialFileName = InitialPath
        .Filters.Clear: .Filters.Add FilterDescription, FilterExtention
        If .Show <> -1 Then Exit Function
        GetFilePath = .SelectedItems(1): PS = Application.PathSeparator
    End With
End Function
 
Sub ПримерИспользования_GetFilePath()
    ИмяФайла = GetFilePath("Выберите файл Word", , "Документы Word", "*.doc") ' запрашиваем имя файла
    If ИмяФайла = "" Then Exit Sub    ' выход, если пользователь отказался от выбора файла
    MsgBox "Выбран файл: " & ИмяФайла, vbInformation
End Sub

Ниже представлены функции для вызова диалоговых окон выбора файлов и папок средствами VBA.

Функции GetFileName и GetFilePath по сути аналогичны, и предназначены для вывода диалогового окна выбора файла
(при этом можно указать стартовую папку для поиска файла, и тип\расширение выбираемого файла)

Функция GetFilenamesCollection позволяет выборать сразу несколько файлов в одной папке.

Функция GetFolderPath работает аналогично, только служит для вывода диалогового окна выбора папки.

Function GetFileName(Optional ByVal Title As String = "Выберите файл для обработки", _
                     Optional ByVal InitialPath, _
                     Optional ByVal MyFilter As String = "Книги Excel (*.xls*),") As String
    ' функция выводит диалоговое окно выбора папки с заголовком Title,
    ' начиная обзор диска с папки InitialPath
    ' возвращает полный путь к выбранной папке, или пустую строку в случае отказа от выбора
    If Not IsMissing(InitialPath) Then
        On Error Resume Next: ChDrive Left(InitialPath, 1)
        ChDir InitialPath    ' выбираем стартовую папку
    End If
    res = Application.GetOpenFilename(MyFilter, , Title, "Открыть")  ' вывод диалогового окна
    GetFileName = IIf(VarType(res) = vbBoolean, "", res)    ' пустая строка при отказе от выбора
End Function
 
Sub ПримерИспользования_GetFileName()
    ИмяФайла = GetFileName("Заголовок окна", ThisWorkbook.Path)   ' запрашиваем имя файла
    ' ===================== другие варианты вызова функции =====================
    ' текстовые файлы, стартовая папка не указана
    '       ИмяФайла = GetFileName("Выберите текстовый файл", , "Текстовые файлы (*.txt),")
    ' файлы любого типа из папки "C:\Windows"
    '       ИмяФайла = GetFileName(, "C:\Windows", "")
    ' ==========================================================================

    If ИмяФайла = "" Then Exit Sub    ' выход, если пользователь отказался от выбора файла
    MsgBox "Выбран файл: " & ИмяФайла, vbInformation
End Sub

Function GetFolderPath(Optional ByVal Title As String = "Выберите папку", _
                       Optional ByVal InitialPath As String = "c:\") As String
    ' функция выводит диалоговое окно выбора папки с заголовком Title,
    ' начиная обзор диска с папки InitialPath
    ' возвращает полный путь к выбранной папке, или пустую строку в случае отказа от выбора
    Dim PS As String: PS = Application.PathSeparator
    With Application.FileDialog(msoFileDialogFolderPicker)
        If Not Right$(InitialPath, 1) = PS Then InitialPath = InitialPath & PS
        .ButtonName = "Выбрать": .Title = Title: .InitialFileName = InitialPath
        If .Show <> -1 Then Exit Function
        GetFolderPath = .SelectedItems(1)
        If Not Right$(GetFolderPath, 1) = PS Then GetFolderPath = GetFolderPath & PS
    End With
End Function
 
Sub ПримерИспользования_GetFolderPath()
    ПутьКПапке = GetFolderPath("Заголовок окна", ThisWorkbook.Path)   ' запрашиваем имя папки
    ' ===================== другие варианты вызова функции =====================
    ' стартовая папка не указана, заголовок окна по умолчанию
    '       ПутьКПапке = GetFolderPath
    ' обзор папок начинается с папки "Рабочий стол"
    '       СтартоваяПапка = CreateObject("WScript.Shell").SpecialFolders("Desktop")
    '       ПутьКПапке = GetFolderPath("Выберите папку на рабочем столе", СтартоваяПапка)
    ' ==========================================================================

    If ПутьКПапке = "" Then Exit Sub    ' выход, если пользователь отказался от выбора папки
    MsgBox "Выбрана папка: " & ПутьКПапке, vbInformation
End Sub

Function GetFilePath(Optional ByVal Title As String = "Выберите файл для обработки", _
                     Optional ByVal InitialPath As String = "c:\", _
                     Optional ByVal FilterDescription As String = "Книги Excel", _
                     Optional ByVal FilterExtention As String = "*.xls*") As String
    ' функция выводит диалоговое окно выбора файла с заголовком Title,
    ' начиная обзор диска с папки InitialPath
    ' возвращает полный путь к выбранному файлу, или пустую строку в случае отказа от выбора
    ' для фильтра можно указать описание и расширение выбираемых файлов
    On Error Resume Next
    With Application.FileDialog(msoFileDialogOpen)
        .ButtonName = "Выбрать": .Title = Title: .InitialFileName = InitialPath
        .Filters.Clear: .Filters.Add FilterDescription, FilterExtention
        If .Show <> -1 Then Exit Function
        GetFilePath = .SelectedItems(1): PS = Application.PathSeparator
    End With
End Function
 
Sub ПримерИспользования_GetFilePath()
     ИмяФайла = GetFilePath("Выберите файл Word", , "Документы Word", "*.doc") ' запрашиваем имя файла
    ' ===================== другие варианты вызова функции =====================
    ' текстовые файлы, стартовая папка не указана
    '       ИмяФайла = GetFilePath("Выберите текстовый файл", , "Текстовые файлы", "*.txt")
    ' файлы любого типа из папки "C:\Windows"
    '       ИмяФайла = GetFilePath(, "C:\Windows", , "*")
    ' ==========================================================================

    If ИмяФайла = "" Then Exit Sub    ' выход, если пользователь отказался от выбора файла
    MsgBox "Выбран файл: " & ИмяФайла, vbInformation
End Sub

Function GetFilenamesCollection(Optional ByVal Title As String = "Выберите файлы для обработки", _
                             Optional ByVal InitialPath As String = "c:\") As FileDialogSelectedItems
    ' функция выводит диалоговое окно выбора нескольких файлов с заголовком Title,
    ' начиная обзор диска с папки InitialPath
    ' возвращает массив путей к выбранным файлам, или пустую строку в случае отказа от выбора
    With Application.FileDialog(3) ' msoFileDialogFilePicker
        .ButtonName = "Выбрать": .Title = Title: .InitialFileName = InitialPath
        If .Show <> -1 Then Exit Function
        Set GetFilenamesCollection = .SelectedItems
    End With
End Function
 
Sub ПримерИспользования_GetFilenamesCollection()
    Dim СписокФайлов As FileDialogSelectedItems
    Set СписокФайлов = GetFilenamesCollection("Заголовок окна", ThisWorkbook.Path)   ' выводим окно выбора
    ' ===================== другие варианты вызова функции =====================
    ' стартовая папка не указана, заголовок окна по умолчанию
           Set СписокФайлов = GetFilenamesCollection
    ' обзор файлов начинается с папки "Рабочий стол"
           СтартоваяПапка = CreateObject("WScript.Shell").SpecialFolders("Desktop")
           Set СписокФайлов = GetFilenamesCollection("Выберите файлы на рабочем столе", СтартоваяПапка)
    ' ==========================================================================

    If СписокФайлов Is Nothing Then Exit Sub  ' выход, если пользователь отказался от выбора файлов
    For Each File In СписокФайлов
        Debug.Print File
    Next
End Sub


Ещё один вариант кода (который я использую) для выбора файла
Его отличие - функция запоминает папку, из которой последний раз выбирался файл,
и при повторном запуске диалогового окна выбора файла,
обзор папок будет начат с той папки, откуда последний раз был взят файл.

Sub AttachFile_test()    ' пример использования
    Filename$ = GetFilePath()
    If Filename$ = "" Then Exit Sub
    MsgBox "Выбран файл: " & Filename$
End Sub
 
Function GetFilePath(Optional ByVal Title As String = "Выберите файл для обработки", _
                     Optional ByVal InitialPath As String = "c:\", _
                     Optional ByVal FilterDescription As String = "Файлы счетов", _
                     Optional ByVal FilterExtention As String = "*.*") As String
    On Error Resume Next
    With Application.FileDialog(msoFileDialogOpen)
        .ButtonName = "Выбрать": .Title = Title:
        .InitialFileName = GetSetting(Application.Name, "GetFilePath", "folder", InitialPath)
        .Filters.Clear: .Filters.Add FilterDescription, FilterExtention
        If .Show <> -1 Then Exit Function
        GetFilePath = .SelectedItems(1)
        folder$ = Left(.SelectedItems(1), InStrRev(.SelectedItems(1), "\"))
        SaveSetting Application.Name, "GetFilePath", "folder", folder$
    End With
End Function

Комментарии

Настройки просмотра комментариев

Выберите нужный метод показа комментариев и нажмите "Сохранить установки".

Этот код написан для Excel. Как сделать в Outlook - не знаю. Попробуйте другие варианты кода из статьи.

Скажите пожалуйста, что делать при ошибке 438. В Outlook ругается на Application.FileDialog(msoFileDialogFolderPicker). Может библиотеку какую подключить и как?

Везде описывается, как задать параметры окна FileDialog (.Title; .InitialFileName; .InitialView; .Filters.Add; .ButtonName). Но нигде не могу найти как задать параметры поиска в верхнем правом углу окна FileDialog?

Вроде иду по правильному пути, вот что получилось:

Function GetFolderPath(Optional ByVal Title As String = "Выберите папки", _
Optional ByVal InitialPath As String = "c:\") As FileDialogSelectedItems

With ТУТ проблема объект FileDialog не дает выбрать только папки, он их открывает (какой объект для папок?)

.ButtonName = "Выбрать": .Title = Title: .InitialFileName = InitialPath
If .Show <> -1 Then Exit Function
Set GetFolderPath = .SelectedItems

End With
End Function

Спасибо Вам большое за макрос. Подскажите, как переделать GetFolderPath так, чтобы можно было выбирать несколько папок, что-то вроде GetFilenamesCollection, но для папок. Заранее спасибо.

Здравствуйте, Дмитрий
Думаю, описанными в статье способами сделать не получится, - так уж устроен Excel и Windows
Зачем вам именно ярлыки? Объясните, - может, посоветую другой способ.

Замечательные функции, активно пользуюсь.
Огромное СПАСИБО
Подскажите, пожалуйста, как из форм выбора выбирать ярлыки
Возвращает сразу объект, а нужен именно ярлык

Вряд ли прояснится, - если мне за несколько последних лет такое не заказывали, и на форумах про подобное не читал, - значит, вероятность найти готовое решение низка.
Сделать можно, если под заказ (не бесплатно)

PS: данная операция возможна, но не штатными средствами Excel
А к прикреплению файлов к книге, это не имеет никакого отношения.

Если проясниться эта ситуация - опишите ее пожалуйста.
По всей видимости данная операция должна быть возможной, поскольку современный Excel имеет возможность прикрепления файлов к книге.

Конечно мне важно именно пермещение фалов на форму и по сложившейся ситуации на работе - не могу писать отдельные проекты ни в VB ни Delphi ни в остальных.
Но, в общем - большое спасибо (за быстрый ответ)!!!

Здравствуйте, Петр

И VB6 это просто делается (примера нет - последний раз делал лет 8 назад) - и список файлов, и перетаскивание

В VBA ни разу не пробовал.
Список файлов несложно сделать (без иконок) - обычный Listbox, куда список файлов загоняется в цикле
Получить список файлов можно этой функцией: http://excelvba.ru/code/FilenamesCollection

Как отловить Drag&Drop для перестаскивания файла - не знаю (события VBA предназначены для отлова перетаскивания ТЕКСТА из поля в поле)
Если использовать сторонние компоненты на форме - то все можно сделать.
Но тут у меня нет опыта - я использую в своих программах только штатные элементы управления.

Добрый день.
Извиняюсь что не совсем по теме, но перерыв интернет не нашел ни одного внятного ответа или примера.
Прошу подсказать по работе с файлами:
1. Есть ли возможность в VBA создать не выбор файлов в диалоговом окне, а выбор файла в элементе управления на форме, который бы отображал содержимое конкретной папки.
2. Возможно ли средствами VBA использовать события Drag&Drop, Drag&Over (у меня они не работают). И как правильно организовать перетаскивание файлов на элемент управления на форме и какой элемент правильней использовать в данном случае.
(элемент InkEdit работает не качественно - не отображает мини-картинку файла exel + выводит картинку, а не ярлык.)
3. Если есть возможность показать пример на эту тему.

заранее, большое спасибо!

Александра, у вас MsgBox отображает корректный путь к файлу?
Если да, - то моя функция работает, ищите проблему в своем коде

Для чего используется метод OpenDatabase?
Много лет пишу макросы - ни разу им не пользовался

Все переменные объявлены: вот более полный вариант кода.
Dim MainFile, InFile, ExFile As String
MainFile = ActiveWindow.Caption
InFile = GetFilePath()
If InFile = "" Then Exit Sub
MsgBox "Âûáðàí ôàéë: " & InFile
Workbooks.OpenDatabase Filename:=InFile _
, CommandText:=Array("Çàäîëæåííîñòü*"), CommandType:=xlCmdTable, _
ImportDataAs:=xlTable

Даже без этой строки происходит ошибка на том же месте, я только что проверила. =(

Добрый день.
Я попробовала ваш код на практике, разобралась в принципе работы, но все равно не могу понять причину ошибки в данной части кода (используется последняя функция в вашей статье):
InFile = GetFilePath()
If InFile = "" Then Exit Sub
MsgBox "Âûáðàí ôàéë: " & InFile
Workbooks.OpenDatabase Filename:=InFile _
, CommandText:=Array("Çàäîëæåííîñòü*"), CommandType:=xlCmdTable, _
ImportDataAs:=xlTable
Ошибка происходит при попытке обработать Workbooks. Согласно Watch, путь к файлу находится корректно, но в filename ничего не прописывается. Не могли бы вы подсказать, в чем тут причина?

Потому что у вас в самом верху модуля есть строка Option Explicit

Или уберите эту строку, или в моём макросе объявляйте все переменные
например, в данном случае

dim ИмяФайла as string

Доброго времени суток.
Почему выходит ошибка(... not defined)при попытке выполнения кода.
ИмяФайла = GetFilePath("Выберите файл excel", , "Документы Excel", "*.xls")

Заранее спасибо

Спасибо большое! все теперь работает!) вы меня просто спасли!)

Попробуйте такой вариант:

Sub Копирование()
 
    Dim sh As Worksheet: Set sh = ActiveSheet        ' запоминаем ссылку на текущий лист

    ИмяФайла = GetFilePath("Выберите файл excel", , "Документы Excel", "*.xls")        ' запрашиваем имя файла
    If ИмяФайла = "" Then Exit Sub        ' выход, если пользователь отказался от выбора файла

    With Workbooks.Open(Filename:=ИмяФайла).Worksheets("исх")
        .Range("$A$8:$AH$30000").AutoFilter Field:=1, Criteria1:="01. Алексеевка"
        .Range("A9:AE5000").Copy
    End With
 
     ' вставляем на лист, который был открыт до вывода диалогового окна выбора файла
   sh.Range("A11").PasteSpecial Paste:=xlPasteValues
 
   Application.CutCopyMode = False ' отключаем режим копирования
End Sub

Добрый день, благодарю за ответ. Код работает. он открывает файл, который я выбираю в директории, меняла я не это. Из этого открытого файла нужно взять с листа значения, соответствующие условию и чтобы они скопировались в текущий. и вот тут я не могу сослаться на этот файл и на этот лист, подскажите пожалуйста, как можно прописать эту строку?

Добрый день, подскажите пожалуйста, взяла за основу Ваш код для открытия файла и добавила в него выбор диапазона

Sub ПримерИспользования_GetFilePath()
ИмяФайла = GetFilePath("Выберите файл excel", , "Документы Excel", "*.xls") ' запрашиваем имя файла
If ИмяФайла = "" Then Exit Sub ' выход, если пользователь отказался от выбора файла
Workbooks.Open Filename:=ИмяФайла
Range("A8").Value = ИмяФайла
Windows("Продажи для ЭТ 2013.xlsx").Activate
Worksheets("исх").Range("$A$8:$AH$30000").AutoFilter Field:=1, Criteria1:= _
"01. Алексеевка"
Range("A9:AE5000").Select
Selection.Copy
Windows("БДР Алексеевка13.xlsm").Activate
Range("A11").Select
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
End Sub

возможно ли как то вместо прописи названия файла "Продажи для ЭТ 2013.xlsx" чтобы он вытаскивал ссылку на этот файл из ячейки А8? если заментить его на "ИмяФайла" выдает ошибку 400.

В статье, в самом конце, приведен рабочий вариант кода для вашего случая.
Вы зачем-то переделали код, - и теперь спрашиваете, почему не работает...
Возьмите код функции GetFolderPath (самый нижний в статье) без переделок, - и всё будет работать корректно.

Доброго времени суток!
Задача: Необходимо чтобы был вывод диалогового окна выбора папки, но при этом он запоминал предыдущий выбор папки.

Из ваших двух макросов сделал один, но есть небольшая проблемка. Он запоминает предыдущий выбор, но при последующим открытии макроса, он выходит на уровень выше (т.е. мы первй раз выбрали C:\Новая папка\Новая папка1\Новая папка2, второй раз запуская макрос мы поподаем на C:\Новая папка\Новая папка1 а я хочу чтобы был путь C:\Новая папка\Новая папка1\Новая папка2 . Пожалуйста, не подскажите как решить данную проблему. Спасибо.

Вот мой макрос:

Sub AttachFile_test() ' пример использования
Filename$ = GetFolderPath()
If Filename$ = "" Then Exit Sub
MsgBox "Выбрана папка: " & Filename$
End Sub

Function GetFolderPath(Optional ByVal Title As String = "Выберите папку", _
Optional ByVal InitialPath As String = "c:\")
On Error Resume Next

With Application.FileDialog(msoFileDialogFolderPicker)
.ButtonName = "Выбрать": .Title = Title:
.InitialFileName = GetSetting("GetFolderPath", "folder", InitialPath)
If .Show <> -1 Then Exit Function
GetFolderPath = .SelectedItems(1)
SaveSetting Application.Name, "GetFolderPath", "folder", GetFolderPath
End With
End Function

PS Я только начал знакомиться с VBA.

Здравствуйте Игорь! Воспользовался вашим примером, функция GetFolderPath. Работает прекрасно. А как сделать, чтобы открывалось не окно Виндовс, а результат прописывался на лист Эксель?

Доброго времени суток!

Подскажите пожалуйста, каким образом будет копироваться все содержимое листа исходя их аналогии кода, который Вы предоставили Станиславу.

Заранее благодарен.

Станислав, вы же видели этот чекбокс в другом моём макросе, - вот и сделайте по аналогии.

Если сами не справитесь, - обратитесь за помощью на форумы по Excel, или оформляйте заказ у меня на сайте

Добрый день! целый день голову ломал, так и не получилось, еще небольшая просьба, необходимо к этому макросу добавить chekbox "Не отображать диалоговое окно выбора папки(искать файлы в ранее выбранной папке)", т.е. чтобы можно было ставить галочку и не выводить каждый раз окно выбора файла, а данные считывались с предыдущего выбранного файла. Заранее спасибо! Вот мой макрос:

все получилось, огромное спасибо!

Станислав, всё делается проще, без активации файлов, листов и окон:

Sub Загрузка_данных()
    On Error Resume Next
    Filename$ = GetFilePath("Выберите файл Excel", "s:\Данные для передачи\", "*.xls")
    If Filename$ = "" Then Exit Sub
    Application.ScreenUpdating = False
 
    Dim sh As Worksheet, WB As Workbook
    Set sh = ActiveSheet
 
    Set WB = Workbooks.Open(Filename$)    'открываем выбранный файл

    WB.Worksheets(1).Range("P6:P36").Copy
    sh.Range("K46").PasteSpecial xlPasteValuesAndNumberFormats, , , True
 
    WB.Worksheets(1).Range("Q6:Q36").Copy
    sh.Range("K48").PasteSpecial xlPasteValuesAndNumberFormats, , , True
 
    Application.CutCopyMode = False
    WB.Close False    ' закрываем файл без сохранения изменений
End Sub

Добрый день! помогите устранить маленькую проблему.
Проблема: в макросе после открытия выбранного файла средствами GetFilePath приходится каждый раз выбранный файл автоматически открывать функцией Workbooks.Open Filename:=ИмяФайла чтобы скопировать несколько ячеек поочередно. Пытался после одного открытия файла просто активировать в дальнейшем функцией Windows(ИмяФайла).Activate указанный файл при открытии. Выкладываю часть макроса, заранее Спасибо!
....
Sub Загрузка_данных()
ИмяФайла = GetFilePath("Выберите файл Excel", "s:\Данные для передачи\", "*.xls")
If ИмяФайла = "" Then Exit Sub
Application.ScreenUpdating = False
Set ActiveWB = ActiveWorkbook
Windows(ActiveWB.Name).Activate
Workbooks.Open Filename:=ИмяФайла 'открываю выбранный файл в первый раз
Range("P6:P36").Select
Selection.Copy
Windows(ActiveWB.Name).Activate
Range("K46").Select
Selection.PasteSpecial Paste:=xlPasteValuesAndNumberFormats, Operation:= _
xlNone, SkipBlanks:=False, Transpose:=True
Workbooks.Open Filename:=ИмяФайла 'вот здесь не хочу заново открывать этот файл, т.к. он уже ранее открыт. а просто его активировать windows().activate как?????
Range("Q6:Q36").Select
Application.CutCopyMode = False
Selection.Copy
Windows(ActiveWB.Name).Activate
Range("K48").Select
Selection.PasteSpecial Paste:=xlPasteValuesAndNumberFormats, Operation:= _
xlNone, SkipBlanks:=False, Transpose:=True
....
ActiveWindow.Close
Range("AA46").Select
Application.ScreenUpdating = True
End Sub

Огромное Вам СПАСИБО!!!

Александр, попробуйте так:

Sub LOADFILE()
    On Error Resume Next
    Filename$ = GetFilePath("Выберите текстовый файл для импорта данных", "G:\Старое\РАБОТА\", "Текстовые файлы", "*.txt")
    If Filename$ = "" Then Exit Sub ' отказы от выбора файла

    With ActiveSheet.QueryTables.Add(Connection:="TEXT;" & Filename$, Destination:=Range("$A$8"))
        .Name = "zv_seg_o"
        ' здесь много строк кода
        .Refresh BackgroundQuery:=False
    End With
End Sub
 
Function GetFilePath(Optional ByVal Title As String = "Выберите файл для обработки", _
                     Optional ByVal InitialPath As String = "c:\", _
                     Optional ByVal FilterDescription As String = "Файлы счетов", _
                     Optional ByVal FilterExtention As String = "*.*") As String
    On Error Resume Next
    With Application.FileDialog(msoFileDialogOpen)
        .ButtonName = "Выбрать": .Title = Title:
        .InitialFileName = GetSetting(Application.Name, "GetFilePath", "folder", InitialPath)
        .Filters.Clear: .Filters.Add FilterDescription, FilterExtention
        If .Show <> -1 Then Exit Function
        GetFilePath = .SelectedItems(1)
        folder$ = Left(.SelectedItems(1), InStrRev(.SelectedItems(1), "\"))
        SaveSetting Application.Name, "GetFilePath", "folder", folder$
    End With
End Function

Как правильно записать макрос для выбора файла и последующей работы с ним? Вопрос в том, что бы можно было выбрать любой файл, а не тот что прописан в макросе (все файлы будут текстовые):

Sub LOADFILE()
    With ActiveSheet.QueryTables.Add(Connection:= "TEXT;G:\Старое\РАБОТА\zv_seg_o.txt", Destination:=Range("$A$8"))
        .Name = "zv_seg_o"
        ' здесь много строк кода
        .Refresh BackgroundQuery:=False
    End With
End Sub

Diana, к сожалению, используемый в коде Application.FileDialog(msoFileDialogOpen) такой возможности не предоставляет.

Можно при желании задать несколько фильтров

' ...
        .Filters.Clear:
        .Filters.Add "Документы Word", "*.doc"
        .Filters.Add "Документы TXT", "*.txt"
        .Filters.Add "Книги Excel", "*.xls*"
' ...

но все фильтры не могут содержать имя файла - а только звездочку с расширением файла.

Здравствуйте. Вопрос по " GetFilePath". Как можно задать в фильтре вместо "*.*", чтобы можно было выбирать только "01.txt", "02.txt", "03.txt", т.е. не все *.txt файлы, а именно перечислить?
И еще... опечаточка на сайте имеется :) ("Функция GetFilenamesCollection позволяет выб!О!рать сразу несколько файлов в одной папке"
Спасибо.

У меня, к счастью (именно, к счастью), тоже нет мака.

Написал небольшую примитивную базку (сам не программист, просто немного умею и быстро учусь при необходимости).

Попросили оптимизировать под мак, т.к. у одного из пользователей яблочный друг. На Windows всё прекрасно работает, а вот на маке форма открывается, на лист данные заносятся без проблем, но эта кнопка не работает, диалоговое окно не открывает, наверняка, и папки не создаёт.

Может из-за того, что там стартовая папка указана "C:\"?

По самому коду есть нарекания, явные ошибки?

Существуют ли альтернативные команды создания директорий и вывода диалоговых окон?

Спасибо!

Здравствуйте, Виктор.
К сожалению, помочь в этом вопросе не смогу, - ибо не являюсь счастливым обладателем Mac-а, и, соответственно, протестировать код на Макинтоше нет никакой возможности.

Доброго времени!

Интересует вопрос, как этот код оптимизировать под Office for mac?

Кнопка открывает диалоговое окно, в нём выбирается нужный файл, при нажатии "открыть", по предустановленному шаблону создаётся папка, в неё копируется выбранный файл, диалоговое окно закрывается. Этот код работает на Windows.

Private Sub Photoprot_bef_oper_but_Click()

File_Path = GetFilePath

St = ActiveWorkbook.Path

SrcFile = File_Path
DestFile = St & "\" & "MRI_CT_Rtg" & "\" & Name_.Text & "_" & Date_hospit.Text & "\" & "6. Фото-видеопротокол" & "_" & Photoprot_bef_oper.Text & "\"

On Error Resume Next

MkDir (St & "\" & "MRI_CT_Rtg" & "\")
MkDir (St & "\" & "MRI_CT_Rtg" & "\" & Name_.Text & "_" & Date_hospit.Text & "\")
MkDir (St & "\" & "MRI_CT_Rtg" & "\" & Name_.Text & "_" & Date_hospit.Text & "\" & "6. Фото-видеопротокол" & "_" & Photoprot_bef_oper.Text)

Set fs = CreateObject("Scripting.FileSystemObject")
fs.CopyFile SrcFile, DestFile

End Sub

Function GetFilePath(Optional ByVal Title As String = "Выберите файл для загрузки", _
Optional ByVal InitialPath As String = "C:\") As String

On Error Resume Next

With Application.FileDialog(msoFileDialogOpen)

.ButtonName = "Выбрать": .Title = Title: .InitialFileName = InitialPath
If .Show <> -1 Then Exit Function
GetFilePath = .SelectedItems(1): PS = Application.PathSeparator

End With

End Function

Необходимо, что бы работало как на винде, так и на мак.

Спасибо!

Сам на свой вопрос ответил )

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim NameRateFile As String
    Dim AskMsg, StyleAskMsg, TitleAskMsg, HelpAskMsg, CtxtAskMsg, ResponseAskMsg, MyStringAskMsg
    Dim AskMsg1, StyleAskMsg1, TitleAskMsg1, HelpAskMsg1, CtxtAskMsg1, ResponseAskMsg1, MyStringAskMsg1
 
    Dim NewFileName As String
    Dim fso As FileSystemObject
    Dim f1, f2 As File
     If Target.Cells.Count > 1 Then Exit Sub
     If Not Application.Intersect(Range("C9:C10"), Target) Is Nothing Then
         UserForm1.Show
     End If
     If Not Application.Intersect(Range("C17:C17"), Target) Is Nothing Then
        'MsgBox "Âûäåëåíà ÿ÷åéêà: "
         NameRateFile = GetFileName("Çàãîëîâîê îêíà", ThisWorkbook.Path)   ' çàïðàøèâàåì èìÿ ôàéëà
        If NameRateFile = "" Then
            NewFileName = ActiveSheet.Name
            Range("C17:C18") = ""
            AskMsg = "Ñîçäàòü ôàéë " + NewFileName + " â òåêóùåé äèðåêòîðèè ?"    ' Define message.
            StyleAskMsg = vbYesNo + vbQuestion + vbDefaultButton2    ' Define buttons
            TitleAskMsg = "Ôàéë íå íàéäå"    ' Define title.
            HelpAskMsg = "DEMO.HLP"    ' Define Help file.
            CtxtAskMsg = 1000    ' Define topic
            ResponseAskMsg = MsgBox(AskMsg, StyleAskMsg, TitleAskMsg, HelpAskMsg, CtxtAskMsg)
 
            AskMsg1 = "Ïåðåçàïèñàòü ñóùåñòâóþùèé ôàéë " + NewFileName + " â òåêóùåé äèðåêòîðèè ?"    ' Define message.
            StyleAskMsg1 = vbYesNo + vbCritical + vbDefaultButton2    ' Define buttons
            TitleAskMsg1 = "ÏÅÐÅÇÀÏÈÑÜ ÔÀÉËÀ"    ' Define title.
            HelpAskMsg1 = "DEMO.HLP"    ' Define Help file.
            CtxtAskMsg1 = 1000    ' Define topic
            
            If ResponseAskMsg = vbYes Then    ' User chose Yes.
                Set fso = CreateObject("Scripting.FileSystemObject")
                On Error Resume Next: ResponseAskMsg1 = MsgBox(AskMsg1, StyleAskMsg1, TitleAskMsg1, HelpAskMsg1, CtxtAskMsg1)
                If ResponseAskMsg1 = vbYes Then
                    Set f2 = fso.CreateTextFile(NewFileName + ".txt", True)
                End If
                If ResponseAskMsg1 = vbNo Then
                    MsgBox "Ôàéë íå âûáðàí è íå ñîçäàí !"
                    Exit Sub
                End If
 
                Set f1 = fso.CreateTextFile(NewFileName + ".txt", False)
                f1.Close
                NameRateFile = ThisWorkbook.Path + "\" + NewFileName + ".txt"
            Else    ' User chose No.
                MsgBox "Ôàéë íå âûáðàí è íå ñîçäàí !"
                Exit Sub
            End If
        End If ' âûõîä, åñëè ïîëüçîâàòåëü îòêàçàëñÿ îò âûáîðà ôàéëà
    MsgBox "Âûáðàí ôàéë: " & NameRateFile, vbInformation
    Range("C17:C17") = NameRateFile
    End If
End Sub

А можно ли сделать так, что если пользователь ввёл в поле "имя файла" что-то сам, а такого файла нет в данной папке, то он создавался автоматически??? Спасибо.

Добрый день!

Все чудесно работает для Excel 2007 и 2003. А как сделать выбор файла (именно файла, а не папки) для Excel 97? Если использовать BrowseForFolder, то какой должен быть синтаксис? У Павла Климова я этого не нашел.

Спасибо!

Спасибо.
Программа с вызовом BrowseForFolder уже есть )) Она дает создавать новую папку.
Но хотелось бы еще иметь возможность
- поиска папки по имени
- задания стартовой папки
подскажите, пожалуйста, можно ли это сделать в 2000

что посоветуете для Excel 2000 ?

Павел Климов на своём сайте msoffice.nm.ru уже дал совет - остаётся лишь процитировать:

Объект FileDialog впервые появился в Microsoft Excel XP
Для выбора папки в более ранних версиях Excel (97, 2000) используйте следующий код:

Sub test()
    Set wshell = CreateObject("Shell.Application")
    On Error Resume Next 'игнорируем ошибку, если нажата Cancel
    Set iPath = wshell.BrowseForFolder(&H0, " Выберите папку....", &H1, 17)
 
    If Not iPath Is Nothing Then
        'FolderPath = iPath.Self.Path 'вариант для WINNT
        FolderPath = iPath.Items.Item.Path    'универсальный вариант для WIN9х/NT
    Else
       Exit Sub 'нажата Cancel
    End If
 
    MsgBox "Выбрана папка: " & FolderPath, vbInformation
End Sub

Добрый день!
В Excel 2000 на оператор

With Application.FileDialog(msoFileDialogFolderPicker)

выдается ошибка 438.
нужно диалоговое окно выбора папки с возможностью
- поиска по имени
- создания новой папки
- задания стартовой папки
что посоветуете для Excel 2000 ?

с диалогами работал, но здесь более элегантно реализовано

функция GetFileName отлично работает. Спасибо.
вместо MsgBox вставил у себя Application.Workbooks.Open ИмяФайла и порядок.
----------
Excel 2007

Отправить комментарий

Содержание этого поля является приватным и не предназначено к показу.
CAPTCHA
Подтвердите, пожалуйста, что вы - человек:
                                        __  __ 
___ _ _ _ _ ___ __ _ | \/ |
/ _ \ | | | | | | | | / __| / _` | | |\/| |
| __/ | |_| | | |_| | | (__ | (_| | | | | |
\___| \__, | \__,_| \___| \__,_| |_| |_|
|___/
Введите код, изображенный в стиле ASCII-арт.

Не получается применить макрос? Не удаётся изменить код под свои нужды?

Оформите заказ у нас на сайте, не забыв прикрепить примеры файлов, и описать, что и как должно работать.